@echo off
chcp 65001 > nul
setlocal

rem CredManager インストールスクリプト
rem 同フォルダの全ファイルを %LOCALAPPDATA%\Programs\CredManager に配置します。
rem 管理者権限不要 (UAC 回避)。同名ファイルは上書き。

set "SRC=%~dp0"
set "DEST=%LOCALAPPDATA%\Programs\CredManager"

echo CredManager をインストールします。
echo   コピー元 : %SRC%
echo   インストール先 : %DEST%
echo.

if not exist "%DEST%" (
    mkdir "%DEST%" 2>nul
    if errorlevel 1 (
        echo [失敗] インストール先ディレクトリを作成できません: %DEST%
        pause
        exit /b 1
    )
)

robocopy "%SRC%." "%DEST%" /E /XF install.bat /NJH /NJS /NDL /NFL
set RC=%ERRORLEVEL%

rem robocopy: 0..7 = success/partial (no change を含む), 8 以上 = 失敗
if %RC% GEQ 8 (
    echo.
    echo [失敗] robocopy エラー: ERRORLEVEL=%RC%
    pause
    exit /b 1
)

echo.
echo [完了] インストール先: %DEST%
echo CredManager.exe を起動するには:
echo     "%DEST%\CredManager.exe"
echo.
pause
exit /b 0
